 |
|
Downloads
|
 |
|
|
|
Forum
|
|
| MEMBERS ONLINE | |
| | We have 382 guests and 1 member online |
You are an anonymous user. You can register for free by clicking here |
| |
|
|
|
Review of the moment
|
|
|
|
 
|
|
|
| Author |
Message |
yoshi41
|
|
Post subject: PockEmul - Sharp Pocket Computer aus den 80ern
 Posted: Feb 05, 2012 - 08:56 PM
|
|
Retrokenner
Joined: Mar 28, 2010
Posts: 683
Location: ประเทศสวิสเซอร์แลนด์
Status: Offline
|
|
Zur Abwechslung mal ein Emulator für Sharp Pocket Computer aus den 80er Jahren. 
Als man Software für Pocket Computer noch selber schreiben musste.
PockEmul
Um so ein Gerät mal kennenzulernen, habe ich für den PC-1403H ein kleines Programm erstellt.
QST! - Der Quer-Summen-Trainer
Code: 1000 : "H":RANDOM
1010 : R=0:F=0:T=0
1020 : Q=0:U=0:Z$=""
1030 : USING "####.#"
1040 : PRINT "QST! R=";STR$ R;" F=";STR$ F;" ";T;"%"
1050 : FOR I=1 TO 5
1060 : X=RND 10:X=X-1:Q=Q+X
1070 : Z$=Z$+STR$ X
1080 : NEXT I
1090 : WAIT 60:PRINT Z$:WAIT
1100 : INPUT "QS ? ";U
1110 : IF U=Q THEN GOTO 1200
1120 : F=F+1
1130 : PRINT STR$ U;" FALSCH ";Z$;" QS ";STR$ Q
1140 : GOTO 1300
1200 : R=R+1
1210 : PRINT STR$ U;" RICHTIG ";Z$;" QS ";STR$ Q
1300 : T=(R*100)/(R+F)
1310 : GOTO 1020
Das Programm zeigt eine 5-stellige Zahl für kurze Zeit an und fordert den Benutzer danach auf, die dazugehörige Quersumme einzugeben.
PC-1403H Memory Dump
Damit Ihr das Programm nicht abtippen müsst, habe ich einen Memory Dump angehängt. Die Datei pc1403h_qst.pkm aus dem Zip einfach in den PockEmul Programm Ordner kopieren.
Zuerst im Emulator eine neue Session für den PC-1403H öffen...
Und dann den Memory Dump pc1403h_qst.pkm laden (rechte Maustaste)...
Mini Tutorial
Aller Anfang ist schwer. Deshalb hier noch ein paar nützliche Informationen zum Starten.
Run / Program Mode
Im Run Mode werden Programme ausgeführt, im Program Mode Programme erstellt und bearbeitet. Die Taste um den Modus zu wechseln heisst meistens MODE (BASIC beim PC-1403H).
Programme können mit einem Label versehen werden. Im QST! Beispiel wurde "H" verwendet, damit das Programm mit den Tasten DEF + H gestartet werden kann.
Programme Editieren (Program Mode)
Mit den Pfeiltasten nach-oben und nach-unten kann durch die Programme geblättert werden.
Mit den links und rechts Pfeiltasten wird die aktuelle Zeile editiert, mit ENTER speichern.
Jede Zeile beginnt mit einer Zeilennummer.
Eine neue Zeile gibt man einfach mit der Zeilennumer und einer Anweisung ein, z.B. 1000 PRINT "HI".
Eine Zeile löschen kann man, indem man einfach nur die Zeilennummer eingibt und ENTER drückt.
Eine Zeile kopieren kann man, indem man eine bestehende Zeilenummer mit einer neuen überschreibt.
Für alles weitere gibt es die Handbücher bei Sharp zum Download...
http://esupport.sharp.de/html/om/index.php?StartRec=10&ListLimit=10&Lang=%&ProdLine=30&SortOrder=DESC&OrderBy=Title&SearchString=&TemplateLang=de&iStart=0
Unglaublich aber wahr, und das nach bald 30 Jahren.  Auch wenn die Qualität zu wünschen übrig lässt, teilweise noch mit Schreibmaschine geschrieben. 
Viel Spass beim Rumprobieren 
EDIT :
Hier noch eine nützliche Kurzanleitung...
http://www.lehmayr.de/PC-1360/d_Manuals/Kurzanleitung.pdf |
_________________ Emulator Packs und Fact Sheets für Wiz, Caanoo, Dingoo und Pandora.
Last edited by yoshi41 on Feb 06, 2012 - 09:59 PM; edited 1 time in total
|
| |
|
|
|
 |
|
krysmopompas
|
|
|
Post subject:
Posted: Feb 05, 2012 - 10:50 PM
|
|
Retrogott
Joined: Jun 19, 2008
Posts: 2.094
Status: Offline
|
|
Ach da werden Erinnerungen wach . Meinen PC1262 habe ich schon lange nicht mehr ausgegraben.
Das waren noch Zeiten als man Programme abtippen oder selberschreiben mußte. Beim Batteriewechsel war dann der Speicher wieder leer  . |
|
_________________
If you can’t run at 60 fps, you’re not a good racing game.
|
| |
|
|
|
|
|
yoshi41
|
|
|
Post subject:
Posted: Feb 05, 2012 - 11:15 PM
|
|
Retrokenner
Joined: Mar 28, 2010
Posts: 683
Location: ประเทศสวิสเซอร์แลนด์
Status: Offline
|
|
Und noch was für den Sharp PC-1350...
Master Mind
Ziel ist es, eine 4-stellige Zahl mit 7 Versuchen zu erraten.
G = Gut (richtige Ziffer, jedoch an der falschen Position)
A = Ass (richtige Ziffer, an der richtigen Position)
Code:
1000 : "M" : CLS : RANDOM : WAIT 59
1002 : CURSOR 3,0 : PRINT "-- Master Mind --"
1004 : CURSOR 7,2 : PRINT "by Yoshi"
1010 : REM INIT
1012 : GOSUB 1200
1020 : REM 7 ROUNDS
1022 : FOR R=0 TO 6
1024 : REM INPUT NUMBER
1026 : GOSUB 1300
1028 : REM CHECK NUMBER
1030 : GOSUB 1400
1032 : REM DISPLAY RESULT
1034 : GOSUB 1500
1036 : IF Y$ = "AAAA" THEN LET R=7
1038 : NEXT R
1050 : IF Y$ = "AAAA" THEN WAIT : CURSOR 12,3 : PRINT "* :-) WON"
1052 : IF Y$ <> "AAAA" THEN WAIT : CURSOR 12,3 : PRINT "* ";S$;" LOST"
1054 : GOTO 1010
1200 : REM INIT
1202 : CLS : WAIT 0 : CLEAR
1204 : DIM MZ$(3)*1
1206 : DIM MI$(3)*1
1208 : DIM MS$(3)*1
1210 : DIM MR$(6)*12
1212 : FOR I=0 to 3
1214 : MZ$(I)=STR$ ((RND 10)-1) : MS$(I)=MZ$(I) : S$=S$+MZ$(I)
1216 : NEXT I
1218 : RETURN
1300 : REM INPUT NUMBER
1302 : CURSOR 12,3 : INPUT "NUM(4) ";X$
1304 : IF LEN (X$) <> 4 THEN GOSUB 1500 : GOTO 1300
1306 : RETURN
1400 : REM CHECK NUMBER
1402 : FOR I=0 TO 3
1404 : MZ$(I)=MS$(I)
1406 : NEXT I
1408 : Y$=""
1420 : FOR I=0 TO 3
1422 : MI$(I)=MID$ (X$,I+1,1)
1424 : IF MI$(I)=MZ$(I) THEN LET Y$=Y$+"A" : MI$(I)="*" : MZ$(I)="#"
1426 : NEXT I
1430 : FOR I=0 TO 3
1432 : FOR J=0 TO 3
1434 : IF MI$(I)=MZ$(J) THEN LET Y$=Y$+"G" : MI$(I)="*" : MZ$(J)="#"
1436 : NEXT J
1438 : NEXT I
1440 : MR$(R)=STR$ (R+1)+" "+X$+" "+Y$
1442 : RETURN
1500 : REM DISPLAY RESULT
1502 : CLS
1504 : FOR I=R TO 0 STEP -1
1506 : H=0 : V=I
1508 : IF I > 3 THEN LET H=12 : V=V-4
1510 : CURSOR H,V : PRINT MR$(I)
1512 : NEXT I
1514 : RETURN
PC-1350 Memory Dump
Damit Ihr das Programm nicht abtippen müsst, habe ich einen Memory Dump angehängt. Die Datei pc1350_master_mind.pkm aus dem Zip einfach in den PockEmul Programm Ordner kopieren.
Zuerst im Emulator eine neue Session für den PC-1350 öffen.
Und dann den Memory Dump pc1350_master_mind.pkm laden (rechte Maustaste)...
Jetzt kann das Programm mit den Tasten DEF + M gestartet werden (im RUN Modus).
PockEmul Multi Session
Der Emulator erlaubt auch mehrere Pocket Computer (Sessions) gleichzeitig laufen zu lassen.
Viel Spass beim Grübeln
Ich frage mich, ob hier überhaupt noch jemand Master Mind kennt... |
_________________ Emulator Packs und Fact Sheets für Wiz, Caanoo, Dingoo und Pandora.
|
| |
|
|
|
|
|
DRK
|
|
|
Post subject:
Posted: Feb 06, 2012 - 12:37 PM
|
|
Asskickers Unite!
Joined: Sep 21, 2004
Posts: 1.836
Location: The Gates of Hell
Status: Offline
|
|
[quote:70681abb66="yoshi41"]Ich frage mich, ob hier überhaupt noch jemand Master Mind kennt...
Ich kenne es!
Vor allem da im TV die Werbung dazu hoch und runter lief!
Irgendwann besaß ich aber auch mal eine Miniversion davon. |
_________________  |
| |
|
|
|
|
|
Ragnarok
|
|
|
Post subject:
Posted: Feb 06, 2012 - 01:23 PM
|
|
Jinxed
Joined: Dec 12, 2006
Posts: 5.397
Location: 기정동
Status: Offline
|
|
|
|
|
|
|
yoshi41
|
|
|
Post subject:
Posted: Feb 06, 2012 - 07:26 PM
|
|
Retrokenner
Joined: Mar 28, 2010
Posts: 683
Location: ประเทศสวิสเซอร์แลนด์
Status: Offline
|
|
[quote:328f0d4122="krysmopompas"]Ach da werden Erinnerungen wach . Meinen PC1262 habe ich schon lange nicht mehr ausgegraben.
Das waren noch Zeiten als man Programme abtippen oder selberschreiben mußte. Beim Batteriewechsel war dann der Speicher wieder leer .Genau so war es. 
Für das dauerhafte Speichern hatte ich mir noch extra einen Data Cassetten Recorder für den PC-1350 gekauft. Neben einem Bandlaufwerkszähler hatte das Teil noch das Feature, Gaps (Leerstellen) auf dem Band zu überspringen, um die gesuchte Datei schneller zu finden. Ansonsten musst man warten, bis der Label mit der normalen Abspielgeschwindigkeit gefunden wurde. Und das konnte dauern. |
_________________ Emulator Packs und Fact Sheets für Wiz, Caanoo, Dingoo und Pandora.
|
| |
|
|
|
|
|
|
|
All times are GMT + 1 Hour
|
|
|
|
|
|
|
|
FAQ
Register
Log in to check your private messages
Log in
